chet01.f

Go to the documentation of this file.

      SUBROUTINE chet01( UPLO, N, A, LDA, AFAC, LDAFAC, IPIV, C, LDC,
     $                   rwork, resid )
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            lda, ldafac, ldc, n
      REAL               resid
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      REAL               rwork( * )
      COMPLEX            a( lda, * ), afac( ldafac, * ), c( ldc, * )
*     ..
*
*  Purpose
*  =======
*
*  CHET01 reconstructs a Hermitian indefinite matrix A from its
*  block L*D*L' or U*D*U' factorization and computes the residual
*     norm( C - A ) / ( N * norm(A) * EPS ),
*  where C is the reconstructed matrix, EPS is the machine epsilon,
*  L' is the conjugate transpose of L, and U' is the conjugate transpose
*  of U.
*
*  Arguments
*  ==========
*
*  UPLO    (input) CHARACTER*1
*          Specifies whether the upper or lower triangular part of the
*          Hermitian matrix A is stored:
*          = 'U':  Upper triangular
*          = 'L':  Lower triangular
*
*  N       (input) INTEGER
*          The number of rows and columns of the matrix A.  N >= 0.
*
*  A       (input) COMPLEX array, dimension (LDA,N)
*          The original Hermitian matrix A.
*
*  LDA     (input) INTEGER
*          The leading dimension of the array A.  LDA >= max(1,N)
*
*  AFAC    (input) COMPLEX array, dimension (LDAFAC,N)
*          The factored form of the matrix A.  AFAC contains the block
*          diagonal matrix D and the multipliers used to obtain the
*          factor L or U from the block L*D*L' or U*D*U' factorization
*          as computed by CHETRF.
*
*  LDAFAC  (input) INTEGER
*          The leading dimension of the array AFAC.  LDAFAC >= max(1,N).
*
*  IPIV    (input) INTEGER array, dimension (N)
*          The pivot indices from CHETRF.
*
*  C       (workspace) COMPLEX array, dimension (LDC,N)
*
*  LDC     (integer) INTEGER
*          The leading dimension of the array C.  LDC >= max(1,N).
*
*  RWORK   (workspace) REAL array, dimension (N)
*
*  RESID   (output) REAL
*          If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS )
*          If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            czero, cone
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info, j
      REAL               anorm, eps
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               clanhe, slamch
      EXTERNAL           lsame, clanhe, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           clavhe, claset
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          aimag, real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         return
      END IF
*
*     Determine EPS and the norm of A.
*
      eps = slamch( 'Epsilon' )
      anorm = clanhe( '1', uplo, n, a, lda, rwork )
*
*     Check the imaginary parts of the diagonal elements and return with
*     an error code if any are nonzero.
*
      DO 10 j = 1, n
         IF( aimag( afac( j, j ) ).NE.zero ) THEN
            resid = one / eps
            return
         END IF
   10 continue
*
*     Initialize C to the identity matrix.
*
      CALL claset( 'Full', n, n, czero, cone, c, ldc )
*
*     Call CLAVHE to form the product D * U' (or D * L' ).
*
      CALL clavhe( uplo, 'Conjugate', 'Non-unit', n, n, afac, ldafac,
     $             ipiv, c, ldc, info )
*
*     Call CLAVHE again to multiply by U (or L ).
*
      CALL clavhe( uplo, 'No transpose', 'Unit', n, n, afac, ldafac,
     $             ipiv, c, ldc, info )
*
*     Compute the difference  C - A .
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 30 j = 1, n
            DO 20 i = 1, j - 1
               c( i, j ) = c( i, j ) - a( i, j )
   20       continue
            c( j, j ) = c( j, j ) - REAL( A( J, J ) )
   30    continue
      ELSE
         DO 50 j = 1, n
            c( j, j ) = c( j, j ) - REAL( A( J, J ) )
            DO 40 i = j + 1, n
               c( i, j ) = c( i, j ) - a( i, j )
   40       continue
   50    continue
      END IF
*
*     Compute norm( C - A ) / ( N * norm(A) * EPS )
*
      resid = clanhe( '1', uplo, n, c, ldc, rwork )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / REAL( N ) ) / anorm ) / eps
      END IF
*
      return
*
*     End of CHET01
*
      END